gui.reactive

import gui.reactive

mut redraws := 0

func main:
    x := reactive.NewInt(1)
    y := reactive.NewInt(2)
    t := reactive.Track((): println "  paint at", x.Get(), y.Get() end, (): redraws++ end).Name("paint")
    x.Set(10)
    y.Set(20)
    println "dirty", t.IsDirty(), "redraw requests", redraws
    println "refreshed", t.Refresh()
    println "refresh with nothing new", t.Refresh()

    reactive.BeginBatch()
    x.Set(3)
    println "in batch", reactive.InBatch(), "requests", redraws
    y.Set(4)
    reactive.EndBatch()
    println "after the batch", redraws
    _r := t.Refresh()

    reactive.Batch(():
        x.Set(5)
        y.Set(6)
    end)
    println "after Batch", redraws
    _r2 := t.Refresh()
    t.Free()
end

import gui.reactive

func main:
    count := reactive.NewInt(0)
    title := reactive.NewStr("")
    title.Bind((): ret "Count: " + count.Get() end)
    h := reactive.OnChange(title, (): println "  title changed to", title.Get() end)
    count.Set(1)
    count.Set(2)
    count.Set(3)
    println "pending", reactive.PendingHandlers()
    println "handlers run", reactive.RunPendingHandlers()
    count.Set(3)
    println "same value", reactive.RunPendingHandlers()
    h.Free()
    count.Set(4)
    println "after Free", reactive.RunPendingHandlers()
end

import gui.reactive
import math

func r3(v: f64): f64:
    ret math.Round(v * 1000.0) / 1000.0
end

func main:
    each e in [reactive.Linear(), reactive.Ease(), reactive.EaseIn(), reactive.EaseOut(), reactive.EaseInOut()]:
        println r3(e.At(0.25)), r3(e.At(0.5)), r3(e.At(0.75))
    end
    custom := reactive.CubicBezier(0.68, -0.6, 0.32, 1.6)
    println "custom", r3(custom.At(0.25)), r3(custom.At(0.75))
    s := reactive.Steps(3, reactive.StepPosition.JumpStart)
    println "steps", s.At(0.0), r3(s.At(0.5)), s.At(1.0)
    p := reactive.ParseEasing("cubic-bezier(0.1, 0.7, 1.0, 0.1)", reactive.Ease())
    println "parsed", p.kind == reactive.EasingKind.CubicBezier, p.x1, p.y1, p.x2, p.y2
    q := reactive.ParseEasing("steps(5, jump-none)", reactive.Ease())
    println "parsed steps", q.steps, q.position == reactive.StepPosition.JumpNone
    bad := reactive.ParseEasing("bounce", reactive.Linear())
    println "fallback", bad.kind == reactive.EasingKind.Linear
end

import conv
import gui.reactive

func main:
    reactive.SetTime(0 as i64)
    left := reactive.NewF64(0.0)
    left.Animate(reactive.Animation { duration = 400, easing = reactive.EaseOut() })
    left.Set(200.0)
    println "running", reactive.AnimationsRunning(), reactive.RunningAnimations()
    until reactive.AnimationsRunning():
        println "t", reactive.Now(), "left", left.Get()
        reactive.AdvanceTime(100 as i64)
    end
    println "t", reactive.Now(), "left", left.Get(), "running", reactive.AnimationsRunning()

    reactive.SetTime(1000 as i64)
    tint := reactive.NewInt(0xFF000000 as int)
    tint.Animate(reactive.Animation { duration = 200, delay = 100, color = true })
    tint.Set(0xFFFFFFFF as int)
    repeat 4 in i:
        reactive.SetTime(1000 as i64 + (i * 100) as i64)
        println "tint", conv.FormatHex(((tint.Get() as i64) & 0xFFFFFFFF) as u64)
    end
end

import gui.reactive

struct Row:
    pub name: str = ""
    pub done: bool = false
end

func main:
    rows := reactive.NewListModel() as reactive.ListModel<Row>
    _id := rows.Listen((ev: reactive.ModelEvent): println "  change", ev.kind as int, "index", ev.index, "count", ev.count end)
    status := reactive.NewStr("")
    status.Bind((): ret "" + rows.Len() + " rows" end)
    rows.Push(Row { name = "milk" })
    rows.Push(Row { name = "bread" })
    rows.Insert(0, Row { name = "eggs" })
    println status.Get(), rows.Get(0).name
    rows.Set(1, Row { name = "milk", done = true })
    rows.Remove(0, 1)
    println status.Get(), rows.Get(0).done
    h := rows.OnChange((): println "  rows changed" end)
    rows.Clear()
    println "handlers", reactive.RunPendingHandlers(), status.Get()
    mut more := Vector {} as Vector<Row>
    more.push(Row { name = "tea" })
    rows.Replace(more)
    more.free()
    rows.Unlisten(_id)
    rows.Push(Row { name = "rice" })
    println status.Get(), reactive.ModelChange.Reset as int
    h.Free()
    rows.Free()
end

import gui.reactive

func main:
    width := reactive.NewInt(3).Name("width")
    height := reactive.NewInt(4).Name("height")
    area := reactive.NewInt(0).Name("area")
    area.Bind((): ret width.Get() * height.Get() end)
    println "area", area.Get(), "bound", area.HasBinding()

    width.Set(10)
    println "dirty after a set", area.IsDirty(), "evaluations so far", reactive.Evaluations()
    println "area", area.Get(), "evaluations so far", reactive.Evaluations()
    println "peek reads without tracking", area.Peek()

    marks := reactive.DirtyMarks()
    height.Set(5)
    height.Set(6)
    println "dirty marks for two sets", reactive.DirtyMarks() - marks

    area.Set(1)
    println "a set replaces the binding", area.HasBinding(), area.Get()
    println "nodes", reactive.LiveNodes(), "edges", reactive.LiveEdges()

    width.Free()
    height.Free()
    area.Free()
    reactive.Reset()
    println "nodes after reset", reactive.LiveNodes()
end

import gui.reactive
import str

func main:
    bytes := reactive.NewI64(3000000000 as i64)
    scale := reactive.NewF64(1.5)
    visible := reactive.NewBool(true)
    name := reactive.NewStr("Sara")
    greeting := reactive.NewStr("")
    greeting.Bind((): ret "Hello, " + name.Get() + "!" end)
    shown := reactive.NewStr("")
    shown.BindCopy((): ret visible.Get() ? name.Get() : "hidden" end)
    println greeting.Get(), shown.Get()
    name.Set("Reza")
    visible.Set(false)
    println greeting.Get(), shown.Get()
    println bytes.Get(), scale.Get() * 2.0

    gap := reactive.ConstInt(8)
    big := reactive.ConstI64(9000000000 as i64)
    ratio := reactive.ConstF64(0.5)
    flag := reactive.ConstBool(true)
    label := reactive.ConstStr("fixed")
    println gap.Get(), big.Get(), ratio.Get(), flag.Get(), label.Get(), "node", gap.node, "fixed", gap.fixed

    kept := str.Clone(greeting.Get())
    name.Set("Mina")
    println "copy kept", kept, "now", greeting.Get()
end

import gui.reactive

struct Size:
    pub w: int = 0
    pub h: int = 0
end

func main:
    window := reactive.NewProp(Size { w = 800, h = 600 }).Name("window size")
    pad := reactive.NewInt(16)
    content := reactive.NewProp(Size {})
    content.Bind(():
        s := window.Get()
        ret Size { w = s.w - 2 * pad.Get(), h = s.h - 2 * pad.Get() }
    end)
    println content.Get(), content.HasBinding()
    h := content.OnChange((): println "  content is now", content.Peek() end)
    window.Set(Size { w = 1024, h = 768 })
    println "handlers", reactive.RunPendingHandlers()
    h.Free()
    window.Free()
    content.Free()
end

import gui.reactive

func main:
    reactive.SetErrorPrinting(false)
    a := reactive.NewInt(0).Name("min width")
    b := reactive.NewInt(0).Name("preferred width")
    a.Bind((): ret b.Get() + 1 end)
    b.Bind((): ret a.Get() + 1 end)
    println "value with the loop cut", a.Get()
    println "errors", reactive.ErrorCount()
    println reactive.LastError()
end