encoding/msgpack

import encoding.msgpack
import encoding.json
import encoding.value
import encoding.encerr
import compress

func main:
    text := `[{"id": 1, "name": "tea", "price": 120, "stock": true},
 {"id": 2, "name": "coffee", "price": 90, "stock": true},
 {"id": 3, "name": "cocoa", "price": 75, "stock": false}]`
    mut e := encerr.NoError()
    rows := json.Decode(text, e)

    compact := json.EncodeDefault(rows)
    packed := msgpack.Marshal(rows)
    println "JSON bytes:       ", compact.len()
    println "MessagePack bytes:", compress.BufLen(packed)

    back := msgpack.Unmarshal(packed, e)
    println "same data:", value.Equal(rows, back), "error:", encerr.IsError(e)
end

import encoding.msgpack
import encoding.value
import compress

func hex(v: value.Value): str:
    digits := "0123456789abcdef"
    mut b := msgpack.Marshal(v)
    mut out := ""
    repeat compress.BufLen(b) in i:
        x := compress.BufGet(b, i)
        if i > 0:
            out = out + " "
        end
        out = out + digits.substr(x / 16, 1) + digits.substr(x % 16, 1)
    end
    compress.BufFree(b)
    ret out
end

func main:
    println "5       ", hex(value.ValueInt(5))
    println "-1      ", hex(value.ValueInt(-1))
    println "200     ", hex(value.ValueInt(200))
    println "70000   ", hex(value.ValueInt(70000))
    println "true    ", hex(value.ValueBool(true))
    println "null    ", hex(value.ValueNull())
    println "1.5     ", hex(value.ValueFloat(1.5))
    println "\"hi\"    ", hex(value.ValueString("hi"))

    mut arr := value.NewValueArray()
    value.ArrayPush(arr, value.ValueInt(1))
    value.ArrayPush(arr, value.ValueInt(2))
    println "[1, 2]  ", hex(arr)

    mut obj := value.NewValueObject()
    value.ObjectSet(obj, "a", value.ValueInt(1))
    println "{\"a\": 1}", hex(obj)
end

import encoding.msgpack
import encoding.json
import encoding.encerr
import compress

struct Session:
    pub user: str = ""
    pub role: str = ""
    pub visits: int = 0
end

func save(cache &: HashMap<str, compress.ByteBuf>, key: str, s: Session):
    mut e := encerr.NoError()
    v := json.Decode(json.Marshal(s), e)
    cache.put(key, msgpack.Marshal(v))
end

func load(cache: HashMap<str, compress.ByteBuf>, key: str, out &: Session): bool:
    if not cache.has(key):
        ret false
    end
    mut e := encerr.NoError()
    v := msgpack.Unmarshal(cache.get(key), e)
    if encerr.IsError(e):
        ret false
    end
    ret json.Unmarshal(json.EncodeDefault(v), out, e)
end

func main:
    mut cache := HashMap {} as HashMap<str, compress.ByteBuf>
    save(cache, "session:9f2", Session { user = "sara", role = "admin", visits = 12 })

    mut s := Session {}
    if load(cache, "session:9f2", s):
        println "found", s.user, s.role, s.visits
    end
    println "missing key loads:", load(cache, "session:000", s)
end

import encoding.msgpack
import encoding.value
import encoding.encerr
import compress

func main:
    mut v := value.NewValueObject()
    value.ObjectSet(v, "name", value.ValueString("salam"))
    b := msgpack.Marshal(v)

    mut e := encerr.NoError()
    whole := msgpack.UnmarshalBytes(b.data, b.len, e)
    println "whole buffer:", encerr.IsError(e), value.AsString(value.ObjectGet(whole, "name"))

    mut cut := encerr.NoError()
    _ := msgpack.UnmarshalBytes(b.data, b.len - 3, cut)
    println "cut short:", encerr.IsError(cut), cut.kind == encerr.KindUnexpectedEOF, cut.message

    mut blob := compress.NewByteBuf()
    compress.BufPush(blob, 0xc4)
    compress.BufPush(blob, 2)
    compress.BufPush(blob, 0xca)
    compress.BufPush(blob, 0xfe)
    mut bin := encerr.NoError()
    _ := msgpack.Unmarshal(blob, bin)
    println "bin from another library:", bin.kind == encerr.KindCustom, bin.message

    mut two := compress.BufClone(b)
    compress.BufPush(two, 0x2a)
    mut extra := encerr.NoError()
    first := msgpack.Unmarshal(two, extra)
    println "extra byte after the value:", encerr.IsError(extra), value.ObjectLen(first), "key read"
end